// workaround for https://github.com/unimodules/react-native-unimodules/issues/52
buildscript {
  repositories {
    google()
    jcenter()
  }

  dependencies {
    classpath 'com.android.tools.build:gradle:3.2.1'
  }
}

apply plugin: 'com.android.library'
apply plugin: 'maven'

group = 'org.unimodules'
version = '2.0.1'

def safeExtGet(prop, fallback) {
  rootProject.ext.has(prop) ? rootProject.ext.get(prop) : fallback
}

//Upload android library to maven with javadoc and android sources
configurations {
  deployerJars
}

//Creating sources with comments
task androidSourcesJar(type: Jar) {
  classifier = 'sources'
  from android.sourceSets.main.java.srcDirs
}

//Put the androidSources and javadoc to the artifacts
artifacts {
  archives androidSourcesJar
}

uploadArchives {
  repositories {
    mavenDeployer {
      configuration = configurations.deployerJars
      repository(url: mavenLocal().url)
    }
  }
}

android {
  compileSdkVersion safeExtGet("compileSdkVersion", 28)

  defaultConfig {
    minSdkVersion safeExtGet("minSdkVersion", 21)
    targetSdkVersion safeExtGet("targetSdkVersion", 28)
    versionCode 8
    versionName "2.0.1"
  }
  lintOptions {
    abortOnError false
  }
}

apply from: project(":unimodules-core").file("../unimodules-core.gradle")

dependencies {
  unimodule 'unimodules-core'
  unimodule 'unimodules-font-interface'
  unimodule 'unimodules-permissions-interface'
  unimodule 'unimodules-image-loader-interface'

//  compileOnly('com.facebook.react:react-native:+') {
//    exclude group: 'com.android.support'
//  }
  implementation 'com.facebook.react:react-native:+'

  implementation 'com.github.bumptech.glide:glide:4.9.0'
}
